net.sourceforge.phpeclipse/src/test/PHPParser.jj

   1 options {
   2   LOOKAHEAD = 1;
   3   CHOICE_AMBIGUITY_CHECK = 2;
   4   OTHER_AMBIGUITY_CHECK = 1;
   5   STATIC = true;
   6   DEBUG_PARSER = false;
   7   DEBUG_LOOKAHEAD = false;
   8   DEBUG_TOKEN_MANAGER = false;
   9   OPTIMIZE_TOKEN_MANAGER = false;
  10   ERROR_REPORTING = true;
  11   JAVA_UNICODE_ESCAPE = false;
  12   UNICODE_INPUT = false;
  13   IGNORE_CASE = true;
  14   USER_TOKEN_MANAGER = false;
  15   USER_CHAR_STREAM = false;
  16   BUILD_PARSER = true;
  17   BUILD_TOKEN_MANAGER = true;
  18   SANITY_CHECK = true;
  19   FORCE_LA_CHECK = false;
  20 }
  21
  22 PARSER_BEGIN(PHPParser)
  23 package test;
  24
  25 import org.eclipse.core.resources.IFile;
  26 import org.eclipse.core.resources.IMarker;
  27 import org.eclipse.core.runtime.CoreException;
  28 import org.eclipse.ui.texteditor.MarkerUtilities;
  29 import org.eclipse.jface.preference.IPreferenceStore;
  30
  31 import java.util.Hashtable;
  32 import java.io.StringReader;
  33 import java.text.MessageFormat;
  34
  35 import net.sourceforge.phpeclipse.actions.PHPStartApacheAction;
  36 import net.sourceforge.phpeclipse.PHPeclipsePlugin;
  37 import net.sourceforge.phpdt.internal.compiler.parser.PHPOutlineInfo;
  38 import net.sourceforge.phpdt.internal.compiler.parser.PHPSegmentWithChildren;
  39 import net.sourceforge.phpdt.internal.compiler.parser.PHPFunctionDeclaration;
  40 import net.sourceforge.phpdt.internal.compiler.parser.PHPClassDeclaration;
  41
  42 /**
  43  * A new php parser.
  44  * This php parser is inspired by the Java 1.2 grammar example
  45  * given with JavaCC. You can get JavaCC at http://www.webgain.com
  46  * You can test the parser with the PHPParserTestCase2.java
  47  * @author Matthieu Casanova
  48  */
  49 public class PHPParser extends PHPParserSuperclass {
  50
  51   private static IFile fileToParse;
  52
  53   /** The current segment */
  54   private static PHPSegmentWithChildren currentSegment;
  55
  56   private static final String PARSE_ERROR_STRING = "Parse error"; //$NON-NLS-1$
  57   private static final String PARSE_WARNING_STRING = "Warning"; //$NON-NLS-1$
  58   public static final int ERROR = 2;
  59   public static final int WARNING = 1;
  60   public static final int INFO = 0;
  61   PHPOutlineInfo outlineInfo;
  62   private static int errorLevel = ERROR;
  63   private static String errorMessage;
  64
  65   public PHPParser() {
  66   }
  67
  68   public void setFileToParse(IFile fileToParse) {
  69     this.fileToParse = fileToParse;
  70   }
  71
  72   public PHPParser(IFile fileToParse) {
  73     this(new StringReader(""));
  74     this.fileToParse = fileToParse;
  75   }
  76
  77   public void phpParserTester(String strEval) throws CoreException, ParseException {
  78     PHPParserTokenManager.SwitchTo(PHPParserTokenManager.PHPPARSING);
  79     StringReader stream = new StringReader(strEval);
  80     if (jj_input_stream == null) {
  81       jj_input_stream = new SimpleCharStream(stream, 1, 1);
  82     }
  83     ReInit(new StringReader(strEval));
  84     phpTest();
  85   }
  86
  87   public void htmlParserTester(String strEval) throws CoreException, ParseException {
  88     StringReader stream = new StringReader(strEval);
  89     if (jj_input_stream == null) {
  90       jj_input_stream = new SimpleCharStream(stream, 1, 1);
  91     }
  92     ReInit(stream);
  93     phpFile();
  94   }
  95
  96   public PHPOutlineInfo parseInfo(Object parent, String s) {
  97     outlineInfo = new PHPOutlineInfo(parent);
  98     currentSegment = outlineInfo.getDeclarations();
  99     StringReader stream = new StringReader(s);
 100     if (jj_input_stream == null) {
 101       jj_input_stream = new SimpleCharStream(stream, 1, 1);
 102     }
 103     ReInit(stream);
 104     try {
 105       parse();
 106     } catch (ParseException e) {
 107       if (errorMessage == null) {
 108         PHPeclipsePlugin.log(e);
 109       } else {
 110         setMarker(errorMessage, e.currentToken.beginLine, errorLevel);
 111         errorMessage = null;
 112       }
 113     }
 114     return outlineInfo;
 115   }
 116
 117
 118   /**
 119    * Create marker for the parse error
 120    */
 121   private static void setMarker(String message, int lineNumber, int errorLevel) {
 122     try {
 123       setMarker(fileToParse, message, lineNumber, errorLevel);
 124     } catch (CoreException e) {
 125       PHPeclipsePlugin.log(e);
 126     }
 127   }
 128
 129   public static void setMarker(IFile file, String message, int lineNumber, int errorLevel) throws CoreException {
 130     if (file != null) {
 131       Hashtable attributes = new Hashtable();
 132       MarkerUtilities.setMessage(attributes, message);
 133       switch (errorLevel) {
 134         case ERROR :
 135           attributes.put(IMarker.SEVERITY, new Integer(IMarker.SEVERITY_ERROR));
 136           break;
 137         case WARNING :
 138           attributes.put(IMarker.SEVERITY, new Integer(IMarker.SEVERITY_WARNING));
 139           break;
 140         case INFO :
 141           attributes.put(IMarker.SEVERITY, new Integer(IMarker.SEVERITY_INFO));
 142           break;
 143       }
 144       MarkerUtilities.setLineNumber(attributes, lineNumber);
 145       MarkerUtilities.createMarker(file, attributes, IMarker.PROBLEM);
 146     }
 147   }
 148
 149   /**
 150    * Create markers according to the external parser output
 151    */
 152   private static void createMarkers(String output, IFile file) throws CoreException {
 153     // delete all markers
 154     file.deleteMarkers(IMarker.PROBLEM, false, 0);
 155
 156     int indx = 0;
 157     int brIndx = 0;
 158     boolean flag = true;
 159     while ((brIndx = output.indexOf("<br />", indx)) != -1) {
 160       // newer php error output (tested with 4.2.3)
 161       scanLine(output, file, indx, brIndx);
 162       indx = brIndx + 6;
 163       flag = false;
 164     }
 165     if (flag) {
 166       while ((brIndx = output.indexOf("<br>", indx)) != -1) {
 167         // older php error output (tested with 4.2.3)
 168         scanLine(output, file, indx, brIndx);
 169         indx = brIndx + 4;
 170       }
 171     }
 172   }
 173
 174   private static void scanLine(String output, IFile file, int indx, int brIndx) throws CoreException {
 175     String current;
 176     StringBuffer lineNumberBuffer = new StringBuffer(10);
 177     char ch;
 178     current = output.substring(indx, brIndx);
 179
 180     if (current.indexOf(PARSE_WARNING_STRING) != -1 || current.indexOf(PARSE_ERROR_STRING) != -1) {
 181       int onLine = current.indexOf("on line <b>");
 182       if (onLine != -1) {
 183         lineNumberBuffer.delete(0, lineNumberBuffer.length());
 184         for (int i = onLine; i < current.length(); i++) {
 185           ch = current.charAt(i);
 186           if ('0' <= ch && '9' >= ch) {
 187             lineNumberBuffer.append(ch);
 188           }
 189         }
 190
 191         int lineNumber = Integer.parseInt(lineNumberBuffer.toString());
 192
 193         Hashtable attributes = new Hashtable();
 194
 195         current = current.replaceAll("\n", "");
 196         current = current.replaceAll("<b>", "");
 197         current = current.replaceAll("</b>", "");
 198         MarkerUtilities.setMessage(attributes, current);
 199
 200         if (current.indexOf(PARSE_ERROR_STRING) != -1)
 201           attributes.put(IMarker.SEVERITY, new Integer(IMarker.SEVERITY_ERROR));
 202         else if (current.indexOf(PARSE_WARNING_STRING) != -1)
 203           attributes.put(IMarker.SEVERITY, new Integer(IMarker.SEVERITY_WARNING));
 204         else
 205           attributes.put(IMarker.SEVERITY, new Integer(IMarker.SEVERITY_INFO));
 206         MarkerUtilities.setLineNumber(attributes, lineNumber);
 207         MarkerUtilities.createMarker(file, attributes, IMarker.PROBLEM);
 208       }
 209     }
 210   }
 211
 212   public void parse(String s) throws CoreException {
 213     ReInit(new StringReader(s));
 214     try {
 215       parse();
 216     } catch (ParseException e) {
 217       if (errorMessage == null) {
 218         PHPeclipsePlugin.log(e);
 219       } else {
 220         setMarker(errorMessage, e.currentToken.beginLine, errorLevel);
 221         errorMessage = null;
 222       }
 223     }
 224   }
 225
 226   /**
 227    * Call the php parse command ( php -l -f &lt;filename&gt; )
 228    * and create markers according to the external parser output
 229    */
 230   public static void phpExternalParse(IFile file) {
 231     IPreferenceStore store = PHPeclipsePlugin.getDefault().getPreferenceStore();
 232     String filename = file.getLocation().toString();
 233
 234     String[] arguments = { filename };
 235     MessageFormat form = new MessageFormat(store.getString(PHPeclipsePlugin.EXTERNAL_PARSER_PREF));
 236     String command = form.format(arguments);
 237
 238     String parserResult = PHPStartApacheAction.getParserOutput(command, "External parser: ");
 239
 240     try {
 241       // parse the buffer to find the errors and warnings
 242       createMarkers(parserResult, file);
 243     } catch (CoreException e) {
 244       PHPeclipsePlugin.log(e);
 245     }
 246   }
 247
 248   public void parse() throws ParseException {
 249           phpFile();
 250   }
 251 }
 252
 253 PARSER_END(PHPParser)
 254
 255 <DEFAULT> TOKEN :
 256 {
 257   <PHPSTART : "<?php" | "<?"> : PHPPARSING
 258 }
 259
 260 <PHPPARSING> TOKEN :
 261 {
 262   <PHPEND :"?>"> : DEFAULT
 263 }
 264
 265 <DEFAULT> SKIP :
 266 {
 267  < ~[] >
 268 }
 269
 270
 271 /* WHITE SPACE */
 272
 273 <PHPPARSING> SKIP :
 274 {
 275   " "
 276 | "\t"
 277 | "\n"
 278 | "\r"
 279 | "\f"
 280 }
 281
 282 /* COMMENTS */
 283
 284 <PHPPARSING> MORE :
 285 {
 286   "//" : IN_SINGLE_LINE_COMMENT
 287 |
 288   <"/**" ~["/"]> { input_stream.backup(1); } : IN_FORMAL_COMMENT
 289 |
 290   "/*" : IN_MULTI_LINE_COMMENT
 291 }
 292
 293 <IN_SINGLE_LINE_COMMENT>
 294 SPECIAL_TOKEN :
 295 {
 296   <SINGLE_LINE_COMMENT: "\n" | "\r" | "\r\n" | "?>" > : PHPPARSING
 297 }
 298
 299 <IN_FORMAL_COMMENT>
 300 SPECIAL_TOKEN :
 301 {
 302   <FORMAL_COMMENT: "*/" > : PHPPARSING
 303 }
 304
 305 <IN_MULTI_LINE_COMMENT>
 306 SPECIAL_TOKEN :
 307 {
 308   <MULTI_LINE_COMMENT: "*/" > : PHPPARSING
 309 }
 310
 311 <IN_SINGLE_LINE_COMMENT,IN_FORMAL_COMMENT,IN_MULTI_LINE_COMMENT>
 312 MORE :
 313 {
 314   < ~[] >
 315 }
 316
 317 /* KEYWORDS */
 318 <PHPPARSING> TOKEN :
 319 {
 320   <CLASS    : "class">
 321 | <FUNCTION : "function">
 322 | <VAR      : "var">
 323 | <IF       : "if">
 324 | <ELSEIF   : "elseif">
 325 | <ELSE     : "else">
 326 | <ARRAY    : "array">
 327 }
 328
 329 /* LANGUAGE CONSTRUCT */
 330 <PHPPARSING> TOKEN :
 331 {
 332   <PRINT : "print">
 333 | <ECHO : "echo">
 334 | <INCLUDE : "include">
 335 | <REQUIRE : "require">
 336 | <INCLUDE_ONCE : "include_once">
 337 | <REQUIRE_ONCE : "require_once">
 338 | <GLOBAL : "global">
 339 | <STATIC : "static">
 340 | <CLASSACCESS: "->">
 341 | <STATICCLASSACCESS: "::">
 342 | <ARRAYASSIGN: "=>">
 343 }
 344
 345 /* RESERVED WORDS AND LITERALS */
 346
 347 <PHPPARSING> TOKEN :
 348 {
 349   < BREAK: "break" >
 350 | < CASE: "case" >
 351 | < CONST: "const" >
 352 | < CONTINUE: "continue" >
 353 | < _DEFAULT: "default" >
 354 | < DO: "do" >
 355 | < EXTENDS: "extends" >
 356 | < FALSE: "false" >
 357 | < FOR: "for" >
 358 | < GOTO: "goto" >
 359 | < NEW: "new" >
 360 | < NULL: "null" >
 361 | < RETURN: "return" >
 362 | < SUPER: "super" >
 363 | < SWITCH: "switch" >
 364 | < THIS: "this" >
 365 | < TRUE: "true" >
 366 | < WHILE: "while" >
 367 | < ENDWHILE : "endwhile" >
 368 }
 369
 370 /* TYPES */
 371
 372 <PHPPARSING> TOKEN :
 373 {
 374   <STRING : "string">
 375 | <OBJECT : "object">
 376 | <BOOL : "bool">
 377 | <BOOLEAN : "boolean">
 378 | <REAL : "real">
 379 | <DOUBLE : "double">
 380 | <FLOAT : "float">
 381 | <INT : "int">
 382 | <INTEGER : "integer">
 383 }
 384
 385 <PHPPARSING> TOKEN :
 386 {
 387   < _ORL : "OR" >
 388 | < _ANDL: "AND">
 389 }
 390
 391 /* LITERALS */
 392
 393 <PHPPARSING> TOKEN :
 394 {
 395   < INTEGER_LITERAL:
 396         <DECIMAL_LITERAL> (["l","L"])?
 397       | <HEX_LITERAL> (["l","L"])?
 398       | <OCTAL_LITERAL> (["l","L"])?
 399   >
 400 |
 401   < #DECIMAL_LITERAL: ["1"-"9"] (["0"-"9"])* >
 402 |
 403   < #HEX_LITERAL: "0" ["x","X"] (["0"-"9","a"-"f","A"-"F"])+ >
 404 |
 405   < #OCTAL_LITERAL: "0" (["0"-"7"])* >
 406 |
 407   < FLOATING_POINT_LITERAL:
 408         (["0"-"9"])+ "." (["0"-"9"])* (<EXPONENT>)? (["f","F","d","D"])?
 409       | "." (["0"-"9"])+ (<EXPONENT>)? (["f","F","d","D"])?
 410       | (["0"-"9"])+ <EXPONENT> (["f","F","d","D"])?
 411       | (["0"-"9"])+ (<EXPONENT>)? ["f","F","d","D"]
 412   >
 413 |
 414   < #EXPONENT: ["e","E"] (["+","-"])? (["0"-"9"])+ >
 415 |
 416   < STRING_LITERAL: (<STRING_1> | <STRING_2> | <STRING_3>)>
 417 |    < STRING_1:
 418       "\""
 419       (   (~["\""])
 420         | "\\\""
 421       )*
 422       "\""
 423     >
 424 |    < STRING_2:
 425       "'"
 426       (   (~["'"]))*
 427
 428       "'"
 429     >
 430 |   < STRING_3:
 431       "`"
 432       (   (~["`"]))*
 433       "`"
 434     >
 435 }
 436
 437 /* IDENTIFIERS */
 438
 439 <PHPPARSING> TOKEN :
 440 {
 441   < IDENTIFIER: (<LETTER>|<SPECIAL>) (<LETTER>|<DIGIT>|<SPECIAL>)* >
 442 |
 443   < #LETTER:
 444       ["a"-"z"] | ["A"-"Z"]
 445   >
 446 |
 447   < #DIGIT:
 448       ["0"-"9"]
 449   >
 450 |
 451   < #SPECIAL:
 452     "_"
 453   >
 454 }
 455
 456 /* SEPARATORS */
 457
 458 <PHPPARSING> TOKEN :
 459 {
 460   < LPAREN: "(" >
 461 | < RPAREN: ")" >
 462 | < LBRACE: "{" >
 463 | < RBRACE: "}" >
 464 | < LBRACKET: "[" >
 465 | < RBRACKET: "]" >
 466 | < SEMICOLON: ";" >
 467 | < COMMA: "," >
 468 | < DOT: "." >
 469 }
 470
 471 /* OPERATORS */
 472
 473 <PHPPARSING> TOKEN :
 474 {
 475   <AT     : "@">
 476 | <DOLLAR : "$">
 477 | < ASSIGN: "=" >
 478 | < GT: ">" >
 479 | < LT: "<" >
 480 | < BANG: "!" >
 481 | < HOOK: "?" >
 482 | < COLON: ":" >
 483 | < EQ: "==" >
 484 | < LE: "<=" >
 485 | < GE: ">=" >
 486 | < NE: "!=" >
 487 | < SC_OR: "||" >
 488 | < SC_AND: "&&" >
 489 | < INCR: "++" >
 490 | < DECR: "--" >
 491 | < PLUS: "+" >
 492 | < MINUS: "-" >
 493 | < STAR: "*" >
 494 | < SLASH: "/" >
 495 | < BIT_AND: "&" >
 496 | < BIT_OR: "|" >
 497 | < XOR: "^" >
 498 | < REM: "%" >
 499 | < LSHIFT: "<<" >
 500 | < RSIGNEDSHIFT: ">>" >
 501 | < RUNSIGNEDSHIFT: ">>>" >
 502 | < PLUSASSIGN: "+=" >
 503 | < MINUSASSIGN: "-=" >
 504 | < STARASSIGN: "*=" >
 505 | < SLASHASSIGN: "/=" >
 506 | < ANDASSIGN: "&=" >
 507 | < ORASSIGN: "|=" >
 508 | < XORASSIGN: "^=" >
 509 | < DOTASSIGN: ".=" >
 510 | < REMASSIGN: "%=" >
 511 | < LSHIFTASSIGN: "<<=" >
 512 | < RSIGNEDSHIFTASSIGN: ">>=" >
 513 | < RUNSIGNEDSHIFTASSIGN: ">>>=" >
 514 }
 515
 516 <PHPPARSING> TOKEN :
 517 {
 518   < DOLLAR_ID: <DOLLAR> <IDENTIFIER>  >
 519 }
 520
 521 /*****************************************
 522  * THE JAVA LANGUAGE GRAMMAR STARTS HERE *
 523  *****************************************/
 524
 525 /*
 526  * Program structuring syntax follows.
 527  */
 528
 529 void phpTest() :
 530 {}
 531 {
 532   Php()
 533   <EOF>
 534 }
 535
 536 void phpFile() :
 537 {}
 538 {
 539   (<PHPSTART> Php() <PHPEND>)*
 540   <EOF>
 541 }
 542
 543 void Php() :
 544 {}
 545 {
 546   (BlockStatement())*
 547 }
 548
 549 void ClassDeclaration() :
 550 {
 551   PHPClassDeclaration classDeclaration;
 552   Token className;
 553   int pos = jj_input_stream.bufpos;
 554 }
 555 {
 556   <CLASS> className = <IDENTIFIER> [ <EXTENDS> <IDENTIFIER> ]
 557   {
 558     classDeclaration = new PHPClassDeclaration(currentSegment,className.image,pos);
 559     currentSegment.add(classDeclaration);
 560     currentSegment = classDeclaration;
 561   }
 562   ClassBody()
 563   {
 564     currentSegment = (PHPSegmentWithChildren) currentSegment.getParent();
 565   }
 566 }
 567
 568 void ClassBody() :
 569 {}
 570 {
 571   <LBRACE> ( ClassBodyDeclaration() )* <RBRACE>
 572 }
 573
 574 void ClassBodyDeclaration() :
 575 {}
 576 {
 577   MethodDeclaration()
 578 |
 579   FieldDeclaration()
 580 }
 581
 582 void FieldDeclaration() :
 583 {}
 584 {
 585   <VAR> VariableDeclarator() ( <COMMA> VariableDeclarator() )* <SEMICOLON>
 586 }
 587
 588 void VariableDeclarator() :
 589 {}
 590 {
 591   VariableDeclaratorId() [ <ASSIGN> VariableInitializer() ]
 592 }
 593
 594 void VariableDeclaratorId() :
 595 {}
 596 {
 597   Variable() ( LOOKAHEAD(2) VariableSuffix() )*
 598 }
 599
 600 void Variable():
 601 {}
 602 {
 603   <DOLLAR_ID> (<LBRACE> Expression() <RBRACE>) *
 604 |
 605   <DOLLAR> VariableName()
 606 }
 607
 608 String VariableName():
 609 {}
 610 {
 611   <LBRACE> Expression() <RBRACE>
 612 |
 613   <IDENTIFIER> (<LBRACE> Expression() <RBRACE>) *
 614 |
 615   <DOLLAR> VariableName()
 616 }
 617
 618 void VariableInitializer() :
 619 {}
 620 {
 621   Expression()
 622 }
 623
 624 void ArrayVariable() :
 625 {}
 626 {
 627   Expression() (<ARRAYASSIGN> Expression())*
 628 }
 629
 630 void ArrayInitializer() :
 631 {}
 632 {
 633   <LPAREN> [ ArrayVariable() ( LOOKAHEAD(2) <COMMA> ArrayVariable() )* ]<RPAREN>
 634 }
 635
 636 void MethodDeclaration() :
 637 {
 638   PHPFunctionDeclaration functionDeclaration;
 639 }
 640 {
 641   <FUNCTION> functionDeclaration = MethodDeclarator()
 642   {
 643     currentSegment.add(functionDeclaration);
 644     currentSegment = functionDeclaration;
 645   }
 646   ( Block() | <SEMICOLON> )
 647   {
 648     currentSegment = (PHPSegmentWithChildren) currentSegment.getParent();
 649   }
 650 }
 651
 652 PHPFunctionDeclaration MethodDeclarator() :
 653 {
 654   Token bit_and = null;
 655   Token identifier;
 656   StringBuffer methodDeclaration = new StringBuffer();
 657   String formalParameters;
 658   int pos = jj_input_stream.bufpos;
 659 }
 660 {
 661   [ bit_and = <BIT_AND>]
 662   identifier = <IDENTIFIER> FormalParameters()
 663   {
 664     if (bit_and != null) {
 665       methodDeclaration.append("&");
 666     }
 667     methodDeclaration.append(identifier);
 668     return new PHPFunctionDeclaration(currentSegment,methodDeclaration.toString(),pos);
 669   }
 670 }
 671
 672 void FormalParameters() :
 673 {}
 674 {
 675   <LPAREN> [ FormalParameter() ( <COMMA> FormalParameter() )* ] <RPAREN>
 676 }
 677
 678 void FormalParameter() :
 679 {}
 680 {
 681   [<BIT_AND>] VariableDeclarator()
 682 }
 683
 684 void Type() :
 685 {}
 686 {
 687   <STRING>
 688 |
 689   <BOOL>
 690 |
 691   <BOOLEAN>
 692 |
 693   <REAL>
 694 |
 695   <DOUBLE>
 696 |
 697   <FLOAT>
 698 |
 699   <INT>
 700 |
 701   <INTEGER>
 702 }
 703
 704 void Expression() :
 705 {}
 706 {
 707   PrintExpression()
 708 |
 709   ConditionalExpression()
 710   [
 711     AssignmentOperator() Expression()
 712   ]
 713 }
 714
 715 void AssignmentOperator() :
 716 {}
 717 {
 718   <ASSIGN> | <STARASSIGN> | <SLASHASSIGN> | <REMASSIGN> | <PLUSASSIGN> | <MINUSASSIGN> | <LSHIFTASSIGN> | <RSIGNEDSHIFTASSIGN> | <RUNSIGNEDSHIFTASSIGN> | <ANDASSIGN> | <XORASSIGN> | <ORASSIGN> | <DOTASSIGN>
 719 }
 720
 721 void ConditionalExpression() :
 722 {}
 723 {
 724   ConditionalOrExpression() [ <HOOK> Expression() <COLON> ConditionalExpression() ]
 725 }
 726
 727 void ConditionalOrExpression() :
 728 {}
 729 {
 730   ConditionalAndExpression() ( (<SC_OR> | <_ORL>) ConditionalAndExpression() )*
 731 }
 732
 733 void ConditionalAndExpression() :
 734 {}
 735 {
 736   ConcatExpression() ( (<SC_AND> | <_ANDL>) ConcatExpression() )*
 737 }
 738
 739 void ConcatExpression() :
 740 {}
 741 {
 742   InclusiveOrExpression() ( <DOT> InclusiveOrExpression() )*
 743 }
 744
 745 void InclusiveOrExpression() :
 746 {}
 747 {
 748   ExclusiveOrExpression() ( <BIT_OR> ExclusiveOrExpression() )*
 749 }
 750
 751 void ExclusiveOrExpression() :
 752 {}
 753 {
 754   AndExpression() ( <XOR> AndExpression() )*
 755 }
 756
 757 void AndExpression() :
 758 {}
 759 {
 760   EqualityExpression() ( <BIT_AND> EqualityExpression() )*
 761 }
 762
 763 void EqualityExpression() :
 764 {}
 765 {
 766   RelationalExpression() ( ( <EQ> | <NE> ) RelationalExpression() )*
 767 }
 768
 769 void RelationalExpression() :
 770 {}
 771 {
 772   ShiftExpression() ( ( <LT> | <GT> | <LE> | <GE> ) ShiftExpression() )*
 773 }
 774
 775 void ShiftExpression() :
 776 {}
 777 {
 778   AdditiveExpression() ( ( <LSHIFT> | <RSIGNEDSHIFT> | <RUNSIGNEDSHIFT> ) AdditiveExpression() )*
 779 }
 780
 781 void AdditiveExpression() :
 782 {}
 783 {
 784   MultiplicativeExpression() ( ( <PLUS> | <MINUS> ) MultiplicativeExpression() )*
 785 }
 786
 787 void MultiplicativeExpression() :
 788 {}
 789 {
 790   UnaryExpression() ( ( <STAR> | <SLASH> | <REM> ) UnaryExpression() )*
 791 }
 792
 793 void UnaryExpression() :
 794 {}
 795 {
 796   <AT> UnaryExpression()
 797 |
 798   ( <PLUS> | <MINUS> ) UnaryExpression()
 799 |
 800   PreIncrementExpression()
 801 |
 802   PreDecrementExpression()
 803 |
 804   UnaryExpressionNotPlusMinus()
 805 }
 806
 807 void PreIncrementExpression() :
 808 {}
 809 {
 810   <INCR> PrimaryExpression()
 811 }
 812
 813 void PreDecrementExpression() :
 814 {}
 815 {
 816   <DECR> PrimaryExpression()
 817 }
 818
 819 void UnaryExpressionNotPlusMinus() :
 820 {}
 821 {
 822   <BANG> UnaryExpression()
 823 |
 824   LOOKAHEAD( <LPAREN> Type() <RPAREN> )
 825   CastExpression()
 826 |
 827   PostfixExpression()
 828 |
 829   Literal()
 830 |
 831   <LPAREN>Expression()<RPAREN>
 832 }
 833
 834 void CastExpression() :
 835 {}
 836 {
 837   <LPAREN> Type() <RPAREN> UnaryExpression()
 838 }
 839
 840 void PostfixExpression() :
 841 {}
 842 {
 843   PrimaryExpression() [ <INCR> | <DECR> ]
 844 }
 845
 846 void PrimaryExpression() :
 847 {}
 848 {
 849   LOOKAHEAD(2)
 850   <IDENTIFIER> <STATICCLASSACCESS> ClassIdentifier() (PrimarySuffix())*
 851 |
 852   PrimaryPrefix() ( PrimarySuffix() )*
 853 |
 854   <ARRAY> ArrayInitializer()
 855 }
 856
 857 void PrimaryPrefix() :
 858 {}
 859 {
 860   <IDENTIFIER>
 861 |
 862   [<BIT_AND>] <NEW> ClassIdentifier()
 863 |
 864   VariableDeclaratorId()
 865 }
 866
 867 void ClassIdentifier():
 868 {}
 869 {
 870   <IDENTIFIER>
 871 |
 872   VariableDeclaratorId()
 873 }
 874
 875 void PrimarySuffix() :
 876 {}
 877 {
 878   Arguments()
 879 |
 880   VariableSuffix()
 881 }
 882
 883 void VariableSuffix() :
 884 {}
 885 {
 886   <CLASSACCESS> VariableName()
 887 |
 888   <LBRACKET> [ Expression() ] <RBRACKET>
 889 }
 890
 891 void Literal() :
 892 {}
 893 {
 894   <INTEGER_LITERAL>
 895 |
 896   <FLOATING_POINT_LITERAL>
 897 |
 898   try {
 899     <STRING_LITERAL>
 900   } catch (TokenMgrError e) {
 901     errorMessage = "unterminated string";
 902     errorLevel   = ERROR;
 903     throw generateParseException();
 904   }
 905 |
 906   BooleanLiteral()
 907 |
 908   NullLiteral()
 909 }
 910
 911 void BooleanLiteral() :
 912 {}
 913 {
 914   <TRUE>
 915 |
 916   <FALSE>
 917 }
 918
 919 void NullLiteral() :
 920 {}
 921 {
 922   <NULL>
 923 }
 924
 925 void Arguments() :
 926 {}
 927 {
 928   <LPAREN> [ ArgumentList() ]
 929   try {
 930     <RPAREN>
 931   } catch (ParseException e) {
 932     errorMessage = "')' expected to close the argument list";
 933     errorLevel   = ERROR;
 934     throw e;
 935   }
 936 }
 937
 938 void ArgumentList() :
 939 {}
 940 {
 941   Expression()
 942   ( <COMMA>
 943       try {
 944         Expression()
 945       } catch (ParseException e) {
 946         errorMessage = "expression expected after a comma in argument list";
 947         errorLevel   = ERROR;
 948         throw e;
 949       }
 950    )*
 951 }
 952
 953 /*
 954  * Statement syntax follows.
 955  */
 956
 957 void Statement() :
 958 {}
 959 {
 960   LOOKAHEAD(2)
 961   Expression()  (<SEMICOLON> | "?>")
 962 |
 963   LOOKAHEAD(2)
 964   LabeledStatement()
 965 |
 966   Block()
 967 |
 968   EmptyStatement()
 969 |
 970   StatementExpression()
 971   try {
 972     <SEMICOLON>
 973   } catch (ParseException e) {
 974     errorMessage = "';' expected after expression";
 975     errorLevel   = ERROR;
 976     throw e;
 977   }
 978 |
 979   SwitchStatement()
 980 |
 981   IfStatement()
 982 |
 983   WhileStatement()
 984 |
 985   DoStatement()
 986 |
 987   ForStatement()
 988 |
 989   BreakStatement()
 990 |
 991   ContinueStatement()
 992 |
 993   ReturnStatement()
 994 |
 995   EchoStatement()
 996 |
 997   IncludeStatement()
 998 |
 999   StaticStatement()
1000 |
1001   GlobalStatement()
1002 }
1003
1004 void IncludeStatement() :
1005 {}
1006 {
1007   <REQUIRE> Expression() (<SEMICOLON> | "?>")
1008 |
1009   <REQUIRE_ONCE> Expression() (<SEMICOLON> | "?>")
1010 |
1011   <INCLUDE> Expression() (<SEMICOLON> | "?>")
1012 |
1013   <INCLUDE_ONCE> Expression() (<SEMICOLON> | "?>")
1014 }
1015
1016 void PrintExpression() :
1017 {}
1018 {
1019   <PRINT> Expression()
1020 }
1021
1022 void EchoStatement() :
1023 {}
1024 {
1025   <ECHO> Expression() (<COMMA> Expression())*
1026   try {
1027     (<SEMICOLON> | "?>")
1028   } catch (ParseException e) {
1029     errorMessage = "';' expected after 'echo' statement";
1030     errorLevel   = ERROR;
1031     throw e;
1032   }
1033 }
1034
1035 void GlobalStatement() :
1036 {}
1037 {
1038   <GLOBAL> VariableDeclaratorId() (<COMMA> VariableDeclaratorId())* (<SEMICOLON> | "?>")
1039 }
1040
1041 void StaticStatement() :
1042 {}
1043 {
1044   <STATIC> VariableDeclarator() (<COMMA> VariableDeclarator())* (<SEMICOLON> | "?>")
1045 }
1046
1047 void LabeledStatement() :
1048 {}
1049 {
1050   <IDENTIFIER> <COLON> Statement()
1051 }
1052
1053 void Block() :
1054 {}
1055 {
1056   <LBRACE> ( BlockStatement() )* <RBRACE>
1057 }
1058
1059 void BlockStatement() :
1060 {}
1061 {
1062   Statement()
1063 |
1064   ClassDeclaration()
1065 |
1066   MethodDeclaration()
1067 }
1068
1069 void LocalVariableDeclaration() :
1070 {}
1071 {
1072   VariableDeclarator() ( <COMMA> VariableDeclarator() )*
1073 }
1074
1075 void EmptyStatement() :
1076 {}
1077 {
1078   <SEMICOLON>
1079 }
1080
1081 void StatementExpression() :
1082 /*
1083  * The last expansion of this production accepts more than the legal
1084  * Java expansions for StatementExpression.  This expansion does not
1085  * use PostfixExpression for performance reasons.
1086  */
1087 {}
1088 {
1089   PreIncrementExpression()
1090 |
1091   PreDecrementExpression()
1092 |
1093   PrimaryExpression()
1094   [
1095    <INCR>
1096   |
1097     <DECR>
1098   |
1099     AssignmentOperator() Expression()
1100   ]
1101 }
1102
1103 void SwitchStatement() :
1104 {}
1105 {
1106   <SWITCH> <LPAREN> Expression() <RPAREN> <LBRACE>
1107     ( SwitchLabel() ( BlockStatement() )* )*
1108   <RBRACE>
1109 }
1110
1111 void SwitchLabel() :
1112 {}
1113 {
1114   <CASE> Expression() <COLON>
1115 |
1116   <_DEFAULT> <COLON>
1117 }
1118
1119 void IfStatement() :
1120 /*
1121  * The disambiguating algorithm of JavaCC automatically binds dangling
1122  * else's to the innermost if statement.  The LOOKAHEAD specification
1123  * is to tell JavaCC that we know what we are doing.
1124  */
1125 {}
1126 {
1127   <IF> Condition("if") Statement() ( LOOKAHEAD(1) ElseIfStatement() )* [ LOOKAHEAD(1) <ELSE> Statement() ]
1128 }
1129
1130 void Condition(String keyword) :
1131 {}
1132 {
1133   try {
1134     <LPAREN>
1135   } catch (ParseException e) {
1136     errorMessage = "'(' expected after " + keyword + " keyword";
1137     errorLevel   = ERROR;
1138     throw e;
1139   }
1140   Expression()
1141   try {
1142      <RPAREN>
1143   } catch (ParseException e) {
1144     errorMessage = "')' expected after " + keyword + " keyword";
1145     errorLevel   = ERROR;
1146     throw e;
1147   }
1148 }
1149
1150 void ElseIfStatement() :
1151 {}
1152 {
1153   <ELSEIF> Condition("elseif") Statement()
1154 }
1155
1156 void WhileStatement() :
1157 {}
1158 {
1159   <WHILE> Condition("while") WhileStatement0()
1160 }
1161
1162 void WhileStatement0() :
1163 {}
1164 {
1165   <COLON> (Statement())* <ENDWHILE> (<SEMICOLON> | "?>")
1166 |
1167   Statement()
1168 }
1169
1170 void DoStatement() :
1171 {}
1172 {
1173   <DO> Statement() <WHILE> Condition("while") (<SEMICOLON> | "?>")
1174 }
1175
1176 void ForStatement() :
1177 {}
1178 {
1179   <FOR> <LPAREN> [ ForInit() ] <SEMICOLON> [ Expression() ] <SEMICOLON> [ ForUpdate() ] <RPAREN> Statement()
1180 }
1181
1182 void ForInit() :
1183 {}
1184 {
1185   LOOKAHEAD(LocalVariableDeclaration())
1186   LocalVariableDeclaration()
1187 |
1188   StatementExpressionList()
1189 }
1190
1191 void StatementExpressionList() :
1192 {}
1193 {
1194   StatementExpression() ( <COMMA> StatementExpression() )*
1195 }
1196
1197 void ForUpdate() :
1198 {}
1199 {
1200   StatementExpressionList()
1201 }
1202
1203 void BreakStatement() :
1204 {}
1205 {
1206   <BREAK> [ <IDENTIFIER> ] <SEMICOLON>
1207 }
1208
1209 void ContinueStatement() :
1210 {}
1211 {
1212   <CONTINUE> [ <IDENTIFIER> ] <SEMICOLON>
1213 }
1214
1215 void ReturnStatement() :
1216 {}
1217 {
1218   <RETURN> [ Expression() ] <SEMICOLON>
1219 }